๑۩۞۩๑ 미련한 未練, 執着으로부터의 自由

무한 AS 중...
리퍼러를 들여다 보다, 허탕치고 돌아가시는 분들을 위하여 포스팅합니다.

저도 MSN을 사용하지만, 이 파일에 대하여 아는 바가 없어, 검색을 해보니,
국내쪽에서는 정확히 아는 사람들이 없는 것 같더군요.

올라온 질문도 별로 없지만,
답변도 정확하지 못하여서, 해외쪽을 뒤져봤습니다.

사용방법은 파일을 다운로드 받으셔서,
대화파일이 있는 폴더에 복사하세요.

그리고, 도스창에서 암호를 입력하면, 일괄적으로 ple파일을 텍스트(txt)파일로 변환합니다.
간단하죠?

첨부파일을 내려받으시거나, 아래의 글을 메모장에 복사하여 붙여넣은후,
확장자 bat로 저장하시면 됩니다.


@ECHO OFF
ECHO.
ECHO DecryptAll v3.2 (C) Created by CookieRevised

REM For detailed comments see EncryptAll_COMMENTED.bat

VERIFY EXTTEST 2>NUL
SETLOCAL ENABLEEXTENSIONS DISABLEDELAYEDEXPANSION
IF ERRORLEVEL 1 GOTO NOEXTENSIONS

FOR %%I IN (REG.EXE) DO SET CMDREG="%%~$PATH:I"
IF NOT EXIST %CMDREG% GOTO NOCMDPROGS

FOR %%I IN (ATTRIB.EXE) DO SET CMDATTRIB="%%~$PATH:I"
IF NOT EXIST %CMDATTRIB% GOTO NOCMDPROGS

FOR %%I IN (~EDAF.TMP ~EDAR.TMP ~EDAS.TMP) DO (
  %CMDATTRIB% %%I -H -S -R 1>NUL
  COPY NUL %%I 1>NUL 2>&1
  IF ERRORLEVEL 1 GOTO NOSAVING
  DEL %%I 1>NUL 2>&1
)

IF /I "%PROCESSOR_ARCHITECTURE%"=="AMD64" SET WOW64=WOW6432NODE\
IF /I "%PROCESSOR_ARCHITECTURE%"=="IA64" SET WOW64=WOW6432NODE\
REM IF DEFINED PROCESSOR_ARCHITEW6432 SET WOW64=WOW6432NODE\

FOR /F "DELIMS=" %%I IN ('%%CMDREG%% QUERY "HKLM\SOFTWARE\%WOW64%Patchou\Messenger Plus! Live" /v AppDir 2^>NUL') DO SET LOGVIEWER=%%I
SET LOGVIEWER=%LOGVIEWER: =    %
SET LOGVIEWER="%LOGVIEWER:~24%\Log Viewer.exe"
IF NOT EXIST %LOGVIEWER% GOTO NOPLUS
DIR *.PLE /S/A-D-H 1>NUL 2>&1 || GOTO NOLOGS

SET PASSWORD=%*
IF "%PASSWORD%"=="" (
  >&3 ECHO.
  >&3 SET /P PASSWORD=Enter the decryption password:
)
IF "%PASSWORD%"=="" GOTO NOPASSWORD

ECHO.
ECHO Decrypting all encrypted logs in current directory and subdirectories...
(ECHO.|SET/P=Current directory: )
CD
ECHO Password used: %PASSWORD%

ECHO.
ECHO Decrypting:
CALL :DECRYPTALL .
IF EXIST ~EDAF.TMP GOTO NOTCOMPLETE
IF EXIST ~EDAR.TMP GOTO NOTCOMPLETE
GOTO SUCCESS

:DECRYPTALL
  FOR %%I IN ("%*\*.PLE") DO (
    ECHO %%I
    %LOGVIEWER% /decrypt="%%~fI" /pwd="%PASSWORD%"
    IF ERRORLEVEL 1 IF NOT ERRORLEVEL 2 (
      %CMDATTRIB% "%%I" -H -S -R 1>NUL
      DEL "%%I" 1>NUL 2>&1
      IF NOT EXIST "%%I" (
        ECHO %%I >> ~EDAS.TMP
      ) ELSE (
        ECHO %%I >> ~EDAR.TMP
      )
    ) ELSE (
      IF ERRORLEVEL 0 IF NOT ERRORLEVEL 1  ECHO ^(ERR_0^) %%I  >> ~EDAF.TMP
      IF ERRORLEVEL 1 IF NOT ERRORLEVEL 2  ECHO ^(ERR_1^) %%I  >> ~EDAF.TMP
      IF ERRORLEVEL 2 IF NOT ERRORLEVEL 3  ECHO ^(ERR_2^) %%I  >> ~EDAF.TMP
      IF ERRORLEVEL 3 IF NOT ERRORLEVEL 4  ECHO ^(ERR_3^) %%I  >> ~EDAF.TMP
      IF ERRORLEVEL 4 IF NOT ERRORLEVEL 5  ECHO ^(ERR_4^) %%I  >> ~EDAF.TMP
      IF ERRORLEVEL 5 IF NOT ERRORLEVEL 6  ECHO ^(ERR_5^) %%I  >> ~EDAF.TMP
      IF ERRORLEVEL 6 IF NOT ERRORLEVEL 7  ECHO ^(ERR_6^) %%I  >> ~EDAF.TMP
      IF ERRORLEVEL 7 IF NOT ERRORLEVEL 8  ECHO ^(ERR_7^) %%I  >> ~EDAF.TMP
      IF ERRORLEVEL 8 IF NOT ERRORLEVEL 9  ECHO ^(ERR_8^) %%I  >> ~EDAF.TMP
      IF ERRORLEVEL 9 IF NOT ERRORLEVEL 10 ECHO ^(ERR_9^) %%I  >> ~EDAF.TMP
      IF ERRORLEVEL 10                     ECHO ^(ERR_10^) %%I >> ~EDAF.TMP
    )
  )
  FOR /D %%I IN ("%*\*.*") DO CALL %0 %%I
GOTO :EOF

:NOEXTENSIONS
  ECHO.
  ECHO ERROR: Command extensions can not be enabled.
  ECHO        (possible cause: wrong DOS/Windows version)
GOTO END

:NOCMDPROGS
  ECHO.
  ECHO ERROR: Some needed command tools are not available.
  ECHO        (FIND.EXE, REG.EXE, ATTRIB.EXE)
GOTO END

:NOSAVING
  ECHO.
  ECHO ERROR: Can't create temporary files.
  ECHO        (possible causes: no administration rights, disk write protected, ...)
GOTO END

:NOPLUS
  ECHO.
  ECHO ERROR: Can't find the log viewer program.
  ECHO        (possible cause: Messenger Plus! Live is not installed properly)
GOTO END

:NOLOGS
  ECHO.
  ECHO There are no encrypted logs found in:
  CD
GOTO END

:NOPASSWORD
  ECHO.
  ECHO No password given.
GOTO END

:SUCCESS
  ECHO.
  ECHO All encrypted logs are successfully decrypted.
GOTO END

:NOTCOMPLETE
  IF EXIST ~EDAS.TMP (
    ECHO.
    ECHO Decryption and cleanup was successful for:
    TYPE ~EDAS.TMP
  )
  IF EXIST ~EDAR.TMP (
    ECHO.
    ECHO Cleanup, after successful decryption, has failed for:
    ECHO -^> ^(possible cause: no administration rights^)
    TYPE ~EDAR.TMP
  )
  IF EXIST ~EDAF.TMP (
    ECHO.
    ECHO Decryption has failed for:
    TYPE ~EDAF.TMP
  )
GOTO END

:END
  DEL ~EDAF.TMP 1>NUL 2>&1
  DEL ~EDAR.TMP 1>NUL 2>&1
  DEL ~EDAS.TMP 1>NUL 2>&1
  >&3 ECHO.
  >&3 ECHO Press any key to end...
  >&3 PAUSE 1>NUL
  >&3 ECHO.